/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this
 * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'

android {
    compileSdkVersion config.compileSdkVersion

    defaultConfig {
        minSdkVersion config.minSdkVersion
        targetSdkVersion config.targetSdkVersion
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"

        kapt {
            arguments {
                arg("room.schemaLocation", "$projectDir/schemas".toString())
            }
        }

        javaCompileOptions {
            annotationProcessorOptions {
                arguments += ["room.incremental": "true"]
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    sourceSets {
        androidTest.assets.srcDirs += files("$projectDir/schemas".toString())
    }
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        freeCompilerArgs += "-Xopt-in=kotlinx.coroutines.ExperimentalCoroutinesApi"
    }
}

dependencies {
    implementation project(':browser-icons')
    implementation project(':browser-state')
    implementation project(':concept-engine')
    implementation project(':concept-fetch')
    implementation project(':feature-customtabs')
    implementation project(':feature-tabs')
    implementation project(':feature-intent')
    implementation project(':feature-session')
    implementation project(':service-digitalassetlinks')
    implementation project(':support-base')
    implementation project(':support-images')
    implementation project(':support-ktx')
    implementation project(':support-utils')

    implementation Dependencies.androidx_browser
    implementation Dependencies.androidx_core_ktx
    implementation Dependencies.androidx_lifecycle_runtime
    implementation Dependencies.kotlin_stdlib
    implementation Dependencies.kotlin_coroutines

    implementation Dependencies.androidx_room_runtime
    kapt Dependencies.androidx_room_compiler

    testImplementation project(':support-test')
    testImplementation project(':support-test-libstate')

    testImplementation Dependencies.androidx_test_core
    testImplementation Dependencies.androidx_test_junit
    testImplementation Dependencies.kotlin_reflect
    testImplementation Dependencies.testing_coroutines
    testImplementation Dependencies.testing_mockito
    testImplementation Dependencies.testing_robolectric

    androidTestImplementation Dependencies.androidx_test_core
    androidTestImplementation Dependencies.androidx_test_runner
    androidTestImplementation Dependencies.androidx_test_rules
    androidTestImplementation Dependencies.androidx_room_testing
}

apply from: '../../../publish.gradle'
ext.configurePublish(config.componentsGroupId, archivesBaseName, project.ext.description)
